http://dieseyer.de • all rights reserved • © 2011 v11.4

'*** v9.6 *** www.dieseyer.de *******************************
'
' Datei: PC-Konfiguration für WinTuC.vbs
' Datei: PCKonfiguration-WinTuC.vbs
' Autor: xxx.dexter.xxx@googlemail.com
' Auf: www.dieseyer.de / www.wintuc.de
'
' http://www.source-center.de/forum/showthread.php?p=78817
' Diese Dienste sollten auf dem Zielrechner wie folgt konfiguriert sein:
' - Arbeitsstationsdienst: (Starttyp = Automatisch)
' - COM+-Ereignissystem: (Starttyp = Manuell)
' - RAS-Verbindungsverwaltung: (Starttyp = Manuell)
' - Remoteprozeduraufruf (RPC): (Starttyp = Automatisch)
' - Remote-Registrierung: (Starttyp = Automatisch)
' - RPC-Locator: (Starttyp = Manuell)
' - Server: (Starttyp = Automatisch)
' - Treibererweiterung für Windows Verwaltungsinstrumentation: (Starttyp = Manuell)
' - Verwaltung für automatische RAS-Verbindung: (Starttyp = Manuell)
' - Windows-Verwaltungsinstrumentation: (Starttyp = Automatisch)
' - WMI-Leistungsadapter: (Starttyp = Manuell)
'
' Ursprünglich war vorgesehen, die PC-Konfiguration vor dem
' 'Freischalten' für WinTuC zu speichern, um diese ggf.
' zurück stellen zu können.
' Da für das 'Freischalten' an dem PC sehr wahrscheinlich
' eine lokale Anmeldung mit einem Admin-User erforderlich
' ist, kann man gleich WinTuC vom USB-Stick starten - damit
' ist der einmalige WinTuC-Einsatz erledigt. Und soll WinTuC
' mehrmals eingesetzt werden, ist das zurück setzen auf eine
' ältere Konfiguration nicht erforderlich.
'
'************************************************************

Option Explicit ' Siehe http://dieseyer.de/dse-wsh-lernen.html#OptionExpl

Dim WSHShell : Set WSHShell = CreateObject("WScript.Shell")
Dim WSHNet : Set WSHNet = WScript.CreateObject("WScript.Network")
Dim fso : Set fso = CreateObject("Scripting.FileSystemObject")

Dim LogDatei : LogDatei = WScript.ScriptFullName & "-" & WSHNet.UserName & "-.log"

' Trace32Log( "-", 0 ) ' erstellt neue LogDatei
Trace32Log " ", 1 ' fügt Leerzeile in LogDatei ein


' WSHShell.Popup "= = = S T A R T = = =", 2, "046 :: " & WScript.ScriptName
Trace32Log "047 :: Start " & WScript.ScriptFullName & " ( " & fso.GetFile( WScript.ScriptFullName ).DateLastModified & " )", 1
Trace32Log "048 :: LogDatei: " & LogDatei, 1
Trace32Log "049 :: PCname: " & WSHNet.ComputerName, 1
Trace32Log "050 :: Angemeldeter User: " & WSHNet.UserName, 1


' *** Die "klassische" Authentifizierung von Netzwerkanmeldungen verwenden!
WshShell.RegWrite "HKEY_LOCAL_MACHINE\SYSTEM\ControlSet001\Control\Lsa\forceguest", "00000000", "REG_DWORD"
Trace32Log "055 :: HKEY_LOCAL_MACHINE\SYSTEM\ControlSet001\Control\Lsa\forceguest, 00000000, REG_DWORD", 1
WshShell.RegWrite "HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\Lsa\forceguest", "00000000", "REG_DWORD"
Trace32Log "057 :: HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\Lsa\forceguest, 00000000, REG_DWORD", 1

' *** "Distributed Common Object Model" aktivieren!
WshShell.RegWrite "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Ole\EnableDCOM", "Y", "REG_SZ"
Trace32Log "061 :: HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Ole\EnableDCOM, Y, REG_SZ", 1

' *** Windows-Firewall konfigurieren
' ->Remoteverwaltung zulassen
Wshshell.Run( "netsh firewall set service type=REMOTEADMIN mode=ENABLE")
Trace32Log "066 :: netsh firewall set service type=REMOTEADMIN mode=ENABLE", 1

' *** Windows-Firewall konfigurieren
' -> Ports öffnen
WshShell.Run( "netsh firewall add portopening protocol=TCP port=135 name=DCOM_TCP mode=ENABLE")
Trace32Log "071 :: netsh firewall add portopening protocol=TCP port=135 name=DCOM_TCP mode=ENABLE", 1
WshShell.Run( "netsh firewall add portopening protocol=TCP port=445 name=SMB_TCP mode=ENABLE")
Trace32Log "073 :: netsh firewall add portopening protocol=TCP port=445 name=SMB_TCP mode=ENABLE", 1
WshShell.Run( "netsh firewall add portopening protocol=TCP port=24158 name=WMI_TCP mode=ENABLE")
Trace32Log "075 :: netsh firewall add portopening protocol=TCP port=24158 name=WMI_TCP mode=ENABLE", 1

WSHShell.Popup "= = = E N D E = = =" & vbCRLF & vbCRLF & WScript.ScriptName, 12, "077 :: " & WScript.ScriptName, vbInformation + 4096
Trace32Log "078 :: Ende " & WScript.ScriptFullName & " ( " & fso.GetFile( WScript.ScriptFullName ).DateLastModified & " )", 1

WScript.Quit


'*** v9.C *** www.dieseyer.de ******************************
Sub Trace32Log( LogTxt, ErrType )
'***********************************************************
' in VBS und HTA verwendbar
' Aufbau einer LOG-Datei für trace32.exe ( SMS Trace;
' ALLES in einer Zeile!):
' <![LOG[...]LOG]!>
' <
' time="08:12:54.309+-60"
' date="03-14-2008"
' component="SrcUpdateMgr"
' context=""
' type="0"
' thread="1812"
' file="productpackage.cpp:97"
' >
'
' "context=" Info wird nicht angezeigt
' type="0" normale Zeie => NEUE LOG-DATEI - ggf. alte überschreiben !!!!!!!!!!!!
' type="1" normale Zeie
' type="2" gelbe Zeie
' type="3" rote Zeie
' type="F" rote Zeie

' "thread=" kann eine Dezimalzahl aufnehmen; trace32 zeigt
' neben der Dezimalzahl in Klammern die entspr.
' Hexadezimalzahl an - z.B. "33 (0x21)"
' "file=" wird in "Source:" angezeigt
'

Dim fso : Set fso = CreateObject("Scripting.FileSystemObject")
Dim LogDateiX, TitelX, Tst, Nr

On Error Resume Next
Tst = KeineLog
On Error Goto 0
If UCase( Tst ) = "JA" Then Exit Sub

On Error Resume Next
TitelX = Titel ' Fehler, wenn die Variable 'Titel' nicht außerhalb der Prozedur definiert wurde
TitelX = title ' Fehler, wenn die Variable 'Titel' nicht außerhalb der Prozedur definiert wurde
If Len( TitelX ) < 2 Then TitelX = document.title ' .hta
If Len( TitelX ) < 2 Then TitelX = WScript.ScriptName ' .vbs
On Error Goto 0

On Error Resume Next
LogDateiX = LogDatei ' wurde die Variable 'LogDatei' nicht außerhalb der Prozedur definiert
If Len( LogDateiX ) < 2 Then LogDateiX = WScript.ScriptFullName & ".log" ' .vbs
If Len( LogDateiX ) < 2 Then LogDateiX = TitelX & ".log" ' .hta
On Error Goto 0

Nr = 0 ' Wenn in Thread die Zeilennummer stehen soll:
Nr = 999999
If Nr = 0 AND InStr( LogTxt, " :" & ": " ) > 0 Then
' Wenn in Thread die Zeilennummer stehen soll - Voraussetzung
' ist eine ZeilenNr. im Format '22 :: '
Nr = LogTxt
Nr = Mid( Nr, 1, InStrRev( Nr, " :" & ": " ) -1 ) ' nach der Zeilennummer
Nr = Mid( Nr, InStrRev( Nr, " " ) + 1 ) ' vor der Zeilennummer
On Error Resume Next : Tst = Int( Nr ) : On Error Goto 0 ' Zeilennummer als (Integer) Zahl
Do ' Tst für Vergleich auf gleiche Länge wie Nr anpassen
If Len( Tst ) = Len( Nr ) Then Exit Do
Tst = "0" & Tst
Loop

If "x" & Tst = "x" & Nr Then
LogTxt = Replace( LogTxt, Tst & " :" & ": ", "" )
Nr = Int( Nr )
End If
End If
If Nr = 999999 Then Nr = 0


' Zwei Nachkommastellen (nach Sekunden) der aktuellen Zeit
' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
Tst = Timer() ' timer() in USA: 1234.22
Tst = Replace( Tst, "," , ".") ' timer() in Deutschland: 123454,12
If InStr( Tst, "." ) = 0 Then Tst = Tst & ".000"
Tst = Mid( Tst, InStr( Tst, "." ), 4 )
If Len( Tst ) < 3 Then Tst = Tst & "0"

' Zeitzone ermitteln - neu (v9.C) und immer richtig(er)
' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
Dim AktDMTF : Set AktDMTF = CreateObject("WbemScripting.SWbemDateTime")
AktDMTF.SetVarDate Now(), True : Tst = Tst & Mid( AktDMTF, 22 ) ' : MsgBox Tst, , "205 :: "
' MsgBox "AktDMTF: '" & AktDMTF & "'", , "206 :: "
Set AktDMTF = nothing

LogTxt = "<![LOG[" & LogTxt & "]LOG]!>"
LogTxt = LogTxt & "<"
LogTxt = LogTxt & "time=""" & Hour( Time() ) & ":" & Minute( Time() ) & ":" & Second( Time() ) & Tst & """ "
LogTxt = LogTxt & "date=""" & Month( Date() ) & "-" & Day( Date() ) & "-" & Year( Date() ) & """ "
LogTxt = LogTxt & "component=""" & TitelX & """ "
LogTxt = LogTxt & "context="""" "
LogTxt = LogTxt & "type=""" & ErrType & """ "
LogTxt = LogTxt & "thread=""" & Nr & """ "
LogTxt = LogTxt & "file=""dieseyer.de"" "
LogTxt = LogTxt & ">"

Tst = 8 ' LOG-Datei erweitern
If ErrType = 0 Then Tst = 2 ' LOG-Datei erneuern (alte löschen, neue erstellen)

On Error Resume Next
If LogTxt = vbCRLF Then fso.OpenTextFile( LogDateiX, Tst, true).WriteLine ( LogTxt )
If not LogTxt = vbCRLF Then fso.OpenTextFile( LogDateiX, Tst, true).WriteLine ( LogTxt )
On Error Goto 0

Set fso = Nothing

End Sub ' Trace32Log( LogTxt, ErrType )

http://dieseyer.de • all rights reserved • © 2011 v11.4