'*** v8.2 *** www.dieseyer.de ****************************
'
' Datei:  html2txt.vbs
' Autor:  dieseyer@gmx.de
' Auf:    www.dieseyer.de
'
' http://www.source-center.de/forum/showthread.php?t=25764
'
' Speichert den Quelltext (ohne Bilder, ohne CSS) in einer
' Datei (die gestartet wird).
'
'*********************************************************

Option Explicit ' Siehe http://dieseyer.de/dse-wsh-lernen.html#OptionExpl

Dim WWWSite       : WWWSite = 	"http://dieseyer.de/tip/all128/index.html"
Dim SpeichernIn   : SpeichernIn =	"C:\html2txt.htm"
				SpeichernIn =	"C:\html2txt.txt"

Call Html2Txt( WWWSite, SpeichernIn )

WScript.CreateObject ("WScript.Shell").Run SpeichernIn

WScript.Quit


'*** v8.2 *** www.dieseyer.de ****************************
Function Html2Txt( SiteHtml, ZielDatei )
'*********************************************************
' On Error Resume Next
  Dim msieapp		: Set msieapp = CreateObject("internetexplorer.application")     'InternetExplorer.Application erstellen
  Dim Txt

  Const READYSTATE_COMPLETE = 4

  With msieapp
    .Navigate (SiteHtml)  'Seite ansteurn
    .Visible = False 'Nicht sichtbar machen

    Do While .Busy
      'warten bis der Ie geladen ist
		WScript.Sleep 50
    Loop

    Do While .ReadyState <> READYSTATE_COMPLETE
      'warten bis die site geladen ist
		WScript.Sleep 50
    Loop

     Txt = .document.documentElement.outerHTML  'in die variable strHtml den Html src speichern
    .Quit   'beenden
  End With

  WScript.CreateObject("Scripting.FileSystemObject").OpenTextFile(ZielDatei, 2, True).write Txt

End Function ' Html2Txt( SiteHtml, ZielDatei )